Excel 基础函数案例详解：用两张示例表掌握 39 个常用函数

用订单明细和商品资料两张示例表，逐个讲解 SUM、IF、XLOOKUP、文本与日期等 39 个 Excel 基础函数的实际写法、结果和使用场景。

作者：黄撑更新于 2026-07-17

上一篇 Excel 常用函数清单解决的是“有哪些函数、分别属于哪一类”。这篇文章只展开其中的 基础函数清单，用同一组订单与商品数据逐个演示公式怎么写、会得到什么结果，以及实际什么时候用。

不用一次记住 39 个函数。先把示例表复制到 Excel 或 WPS，再跟着案例输入公式，理解速度会比只看语法快得多。

EXCEL PRACTICE WORKBOOK用两张示例表，完成 6 类真实表格任务

所有案例共用同一组数据。读者不需要频繁切换背景，只需要观察：公式处理了哪一列、条件写在哪里、最后返回什么。

39基础函数

2示例工作表

6任务分组

3组合练习

01统计数量、金额、极值

→

02条件汇总按平台和状态统计

→

03查找按商品编码补资料

→

04清洗拆分和整理文本

→

05判断生成状态和提醒

→

06日期提取年月日

先准备两张示例表

新建一个工作簿，并建立 订单明细 和 商品表 两个工作表。下面所有公式都以这两张表的单元格位置为准。

订单明细

工作表订单明细列较多，可横向查看

	A	B	C	D	E	F	G	H	I	J
1	日期	订单号	平台	商品编码	商品标题	销量	销售额	库存	状态	负责人
2	2026/7/1	TB-260701-001	淘宝	KB001	蓝牙键盘黑色	3	297	12	正常	小林
3	2026/7/1	JD-260701-002	京东	MS002	无线鼠标白色	5	245	6	缺货	小周
4	2026/7/2	PD-260702-003	拼多多	KB001	蓝牙键盘黑色	8	792	4	预警
5	2026/7/3	TB-260703-004	淘宝	CS003	平板保护套蓝色	2	158	18	正常	小林
6	2026/7/4	JD-260704-005	京东	KB004	机械键盘青轴	6	594	7	下架	小陈
7	2026/7/5	TB-260705-006	淘宝	MS002	无线鼠标白色	0	0	20	正常

商品表

工作表商品表查找函数从这里返回资料

	A	B	C	D
1	商品编码	商品名称	标准售价	供应商
2	KB001	蓝牙键盘	99	键盘供应商 A
3	MS002	无线鼠标	49	鼠标供应商 B
4	CS003	平板保护套	79	配件供应商 C
5	KB004	机械键盘	99	键盘供应商 A

表格上方的字母是 Excel 列标，左侧数字是工作表行号，它们都不属于数据。后文出现 F2:F7、C2:C7 或 商品表!A2:A5 时，都可以直接回到这里定位。

每个案例都按同一顺序练习

Step 1 先看要解决的问题

确认是在求总数、按条件统计、查资料，还是处理文字和日期。

Step 2 再看公式引用了哪里

识别数据区域、条件区域、查找值和返回区域分别是什么。

Step 3 对照预期结果

结果不一致时，优先检查区域是否少选一行、条件文字是否写错。

Step 4 修改数据验证理解

改变一条源数据，先猜结果，再让 Excel 重新计算。

一、基础统计与数值处理

这一组函数回答的是最直接的问题：一共有多少、平均是多少、最大最小是多少，以及结果应该保留几位或按什么方式取整。

	F
1	销量
2	3
3	5
4	8
5	2
6	6
7	0

蓝框区域：F2:F7

→

统计公式=SUM(F2:F7)把 F 列第 2～7 行全部相加

→

结果24

SUM求和

问题：6 条记录一共卖了多少件？

=SUM(F2:F7)

结果: 24
关键点: 把 F2 到 F7 的所有数字相加。

AVERAGE平均值

问题：每条记录的平均销量是多少？

=AVERAGE(F2:F7)

结果: 4
关键点: 总销量 24 除以 6 条数字记录。

MAX最大值

问题：单条记录最高销售额是多少？

=MAX(G2:G7)

结果: 792
关键点: 只返回最大数字，不返回它所在的商品。

MIN最小值

问题：当前最低库存是多少？

=MIN(H2:H7)

结果: 4
关键点: 区域中如果包含 0，0 也会参与最小值计算。

COUNT统计数字

问题：销量列中有多少个数字单元格？

=COUNT(F2:F7)

结果: 6
关键点: 数字 0 会计数；文字和真正的空白不会计数。

COUNTA统计非空

问题：商品编码列一共填写了多少条？

=COUNTA(D2:D7)

结果: 6
关键点: 数字、文字、日期都算，只要单元格不是空白。

COUNTBLANK统计空白

问题：有多少条记录还没有填写负责人？

=COUNTBLANK(J2:J7)

结果: 2
关键点: 适合检查必填资料遗漏，但要注意公式返回的空文本也可能被视为空白。

ROUND四舍五入

问题：平均销售额保留两位小数。

=ROUND(SUM(G2:G7)/COUNT(G2:G7),2)

结果: 347.67
关键点: 第二个参数 2 表示保留两位小数。

ROUNDUP向上取整

问题：53 件商品每箱装 24 件，至少需要多少箱？

=ROUNDUP(53/24,0)

结果: 3
关键点: 只要还有零散商品，就必须再增加一箱。

ROUNDDOWN向下取整

问题：53 件商品最多能装满多少整箱？

=ROUNDDOWN(53/24,0)

结果: 2
关键点: 舍去不足一整箱的部分，只保留完整数量。

二、按条件统计与汇总

条件函数由两部分组成：先判断哪些行符合条件，再对符合条件的记录计数、求和或求平均。

	C	G	I
1	平台	销售额	状态
2	淘宝	297	正常
3	京东	245	缺货
4	拼多多	792	预警
5	淘宝	158	正常
6	京东	594	下架
7	淘宝	0	正常

绿色行：两个条件同时成立297 + 158 + 0 = 455

SUMIFS 代表案例=SUMIFS(G2:G7,C2:C7,"淘宝",I2:I7,"正常")

汇总区域G2:G7相加销售额

条件区域 1C2:C7平台等于淘宝

条件区域 2I2:I7状态等于正常

筛出淘宝→再保留正常→汇总 G 列：455

COUNTIF单条件计数

问题：淘宝平台共有多少条记录？

=COUNTIF(C2:C7,“淘宝”)

结果: 3
关键点: 条件区域是平台列，条件文字必须与单元格内容一致。

COUNTIFS多条件计数

问题：淘宝平台中状态正常的记录有多少条？

=COUNTIFS(C2:C7,“淘宝”,I2:I7,“正常”)

结果: 3
关键点: 每个条件都必须同时成立，所有条件区域行数要一致。

SUMIF单条件求和

问题：商品编码 KB001 一共卖了多少件？

=SUMIF(D2:D7,“KB001”,F2:F7)

结果: 11
关键点: 先在 D 列找 KB001，再把对应行的 F 列销量相加。

SUMIFS多条件求和

问题：淘宝平台中状态正常的销售额是多少？

=SUMIFS(G2:G7,C2:C7,“淘宝”,I2:I7,“正常”)

结果: 455
关键点: SUMIFS 的第一个参数先写要汇总的区域。

AVERAGEIF条件平均

问题：京东平台每条记录的平均销售额是多少？

=AVERAGEIF(C2:C7,“京东”,G2:G7)

结果: 419.5
关键点: 只计算京东对应的 245 和 594，不包含其他平台。

三、根据商品编码查找资料

订单明细里通常只有商品编码，名称、标准售价和供应商维护在另一张商品表中。查找函数的任务，就是根据编码把对应资料带回来。

XLOOKUP 和 XMATCH 需要较新的 Excel 或 WPS 版本。旧版本无法识别时，可以继续使用 VLOOKUP，或组合 INDEX 与 MATCH。

一步返回VLOOKUP / XLOOKUP

给出商品编码，直接返回名称、价格或供应商。

或

先定位再取值MATCH / XMATCH → INDEX

先找到相对位置，再按位置返回内容。

订单明细

	D
1	商品编码
2	KB001

查找值：订单明细!D2

→

商品表

	A	B	C	D
1	编码	名称	售价	供应商
2	KB001	蓝牙键盘	99	键盘供应商 A

A2 命中后，可从同一行返回 B2、C2 或 D2

这一节只保留每个函数的最短用法。需要逐个查看公式参数、表格命中位置和返回过程，可以继续阅读 VLOOKUP、XLOOKUP、INDEX、MATCH、XMATCH 可视化指南。

VLOOKUP纵向查找

问题：根据订单明细 D2 的 KB001，返回商品名称。

=VLOOKUP(D2,商品表!$A$2:$D$5,2,FALSE)

结果: 蓝牙键盘
关键点: 编码必须位于查找区域第一列；FALSE 表示精确匹配。

XLOOKUP按值查找

问题：根据订单明细 D3 的 MS002，返回标准售价。

=XLOOKUP(D3,商品表!A2:A5,商品表!C2:C5,“未找到”)

结果: 49
关键点: 查找区域和返回区域分开写，不要求返回列位于右侧。

INDEX按位置取值

问题：返回商品名称区域中的第 3 个值。

=INDEX(商品表!B2:B5,3)

结果: 平板保护套
关键点: INDEX 本身按位置取值，不负责判断商品编码。

MATCH查找位置

问题：CS003 在商品编码区域中排第几个？

=MATCH(“CS003”,商品表!A2:A5,0)

结果: 3
关键点: 返回相对位置，不直接返回商品名称；0 表示精确匹配。

XMATCH新版位置查找

问题：KB004 在商品编码区域中排第几个？

=XMATCH(“KB004”,商品表!A2:A5)

结果: 4
关键点: 默认就是精确匹配，写法比 MATCH 更简洁。

四、拆分、清洗和拼接文本

文本函数经常用于订单号、商品编码、标题和复制出来的脏数据。重点不是背字符位置，而是先看文本格式是否固定。

订单号TB-260701-001商品标题蓝牙键盘黑色脏文本··蓝牙键盘···黑色··圆点代表多余空格，只用于展示。

来源单元格订单明细!B2TB-260701-001

TB-260701-001

12345678910111213

LEFT(B2,2) → TBMID(B2,4,6) → 260701RIGHT(B2,3) → 001

LEFT从左截取

问题：从订单号中提取前两位平台代码。

=LEFT(B2,2)

结果: TB
关键点: 第二个参数表示从左侧取几个字符。

RIGHT从右截取

问题：提取订单号最后三位流水号。

=RIGHT(B2,3)

结果: 001
关键点: 适合固定长度的尾号、规格后缀和编码末段。

MID从中间截取

问题：从订单号中提取 260701 这段日期代码。

=MID(B2,4,6)

结果: 260701
关键点: 从第 4 个字符开始，连续截取 6 个字符。

LEN计算字符数

问题：检查订单号一共有多少个字符。

=LEN(B2)

结果: 13
关键点: 英文、数字、短横线和空格都会各占一个字符。

TRIM清理多余空格

问题：K2 中保存了“ 蓝牙键盘黑色 ”，需要清理空格。

=TRIM(K2)

结果: 蓝牙键盘黑色
关键点: 删除前后空格，并把文字中间连续空格压缩为一个。

SUBSTITUTE按内容替换

问题：把商品标题中的“黑色”统一改成“曜石黑”。

=SUBSTITUTE(E2,“黑色”,“曜石黑”)

结果: 蓝牙键盘曜石黑
关键点: 按具体文字替换，不需要知道文字位于第几个字符。

TEXTJOIN批量拼接

问题：把平台、商品编码和状态拼成一个处理标记。

=TEXTJOIN(”-“,TRUE,C2,D2,I2)

结果: 淘宝-KB001-正常
关键点: 第一个参数是分隔符，TRUE 表示忽略空白单元格。

FIND精确查找位置

问题：第一个短横线位于订单号第几个字符？

=FIND(”-“,B2)

结果: 3
关键点: 区分英文大小写；找不到时会返回错误。

SEARCH查找关键词位置

问题：商品标题中“蓝牙”从第几个字符开始？

=SEARCH(“蓝牙”,E2)

结果: 1
关键点: 不区分英文大小写，更适合一般关键词检查。

五、根据条件生成状态和提醒

逻辑函数不会改变源数据，它们负责把数据转换成更容易处理的结果，例如“正常”“预警”“需要补货”。

订单明细第 4 行F4 销量 = 8H4 库存 = 4

→

IFS 第一个条件H4 < 5 是否成立？4 < 5，结果为 TRUE

→

输出紧急

IF单层判断

问题：库存低于 10 时显示“库存不足”。

=IF(H3<10,“库存不足”,“正常”)

结果: 库存不足
关键点: 条件成立返回第二个参数，不成立返回第三个参数。

IFS多层判断

问题：库存低于 5 为紧急，低于 10 为预警，其余正常。

=IFS(H4<5,“紧急”,H4<10,“预警”,TRUE,“正常”)

结果: 紧急
关键点: 从左到右判断，命中第一个成立条件后停止。

AND同时满足

问题：库存低于 10 且本次销量不少于 5 时立即补货。

=IF(AND(H4<10,F4>=5),“立即补货”,“继续观察”)

结果: 立即补货
关键点: AND 中所有条件都成立时才返回 TRUE。

OR满足任意一个

问题：状态为缺货或下架时，都标记为需要处理。

=IF(OR(I3=“缺货”,I3=“下架”),“需要处理”,“正常”)

结果: 需要处理
关键点: OR 只要有一个条件成立，就返回 TRUE。

IFERROR处理错误

问题：销量为 0 时无法计算单件金额，不要显示错误代码。

=IFERROR(G7/F7,0)

结果: 0
关键点: 原公式会出现 #DIV/0!，出错后改为返回 0。

六、获取和拆分日期

Excel 中的日期不是普通文字，而是一种可以计算的数值。日期函数可以获取当前时间，也可以把一个完整日期拆成年、月、日。

订单明细!A22026/7/1真实日期值，可以继续计算

→

YEAR(A2)2026年

MONTH(A2)7月

DAY(A2)1日

TODAY当前日期

问题：在表格中显示今天的日期。

=TODAY()

结果: 显示打开表格当天的日期
关键点: 函数没有参数，但括号不能省略；重新计算时会自动更新。

NOW当前日期时间

问题：记录报表当前的计算日期和时间。

=NOW()

结果: 显示当前日期、小时和分钟
关键点: 它会继续变化，不适合当作永久不变的操作时间戳。

YEAR提取年份

问题：从 A2 的日期中提取年份。

=YEAR(A2)

结果: 2026
关键点: 结果是数字，可以继续参与筛选、统计和拼接。

MONTH提取月份

问题：从 A2 的日期中提取月份。

=MONTH(A2)

结果: 7
关键点: 返回 1 到 12 的数字，不会自动显示“7 月”。

DAY提取日

问题：从 A2 的日期中提取一个月中的第几天。

=DAY(A2)

结果: 1
关键点: 返回日期中的“日”，不是星期几，也不是相差天数。

三个组合练习

单个函数掌握后，可以开始组合。下面三个练习仍然只使用本文出现过的基础函数。

练习 01 · 查找与错误处理根据商品编码返回供应商，查不到时显示“未维护”=IFERROR(XLOOKUP(D2,商品表!A2:A5,商品表!D2:D5),“未维护”)

XLOOKUP 负责查资料，IFERROR 负责处理查不到或公式异常。

练习 02 · 汇总与判断某商品总销量不少于 10 件时显示“重点商品”=IF(SUMIF($D$2:$D$7,D2,$F$2:$F$7)>=10,“重点商品”,“普通商品”)

SUMIF 汇总同一商品编码的销量，IF 再把数字转换成状态。

练习 03 · 文本检查与错误处理标题包含“蓝牙”时显示“蓝牙类”，否则显示“其他”=IF(IFERROR(SEARCH(“蓝牙”,E2),0)>0,“蓝牙类”,“其他”)

SEARCH 找到关键词时返回位置，找不到时由 IFERROR 转成 0。

最后怎么判断自己是否学会

01看到“总数、平均、最大最小”能想到 SUM、AVERAGE、MAX、MIN。

02看到“只统计某个平台或状态”能想到 COUNTIF(S)、SUMIF(S)、AVERAGEIF。

03看到“根据编码补名称或价格”能想到 VLOOKUP、XLOOKUP 或 INDEX + MATCH。

04看到“编码拆分、标题清洗、文字拼接”能从 LEFT、MID、TRIM、TEXTJOIN 等函数中选择。

05看到“达标、预警、异常”能用 IF、IFS、AND、OR 写出判断条件。

06看到“年份、月份、今天”能区分 TODAY、NOW、YEAR、MONTH、DAY。